QR code

Bonjour,
je ne sais pas si tu es passé par

Bonjour visiteur, Merci de vous Inscrire ou de vous connectez pour voir les liens!

et ce que tu en penses.

 

Bonjour,

Déjà, un bonjour et un merci est le bienvenu (la B A Ba de la politesse quoi )

Pour lire via webcam j'intègre ceci dans webdev

Bonjour visiteur, Merci de vous Inscrire ou de vous connectez pour voir les liens!

cela fonctionne bien si la tablette est de bonne qualité et asse performante.

Bon dev

 

dans ce cas c'est pareille, c'est html5 et plugin JS, cette technique fonctionne quelque soit l'OS, chrome marche nickel avec le plugin

 

Bonjour visiteur, Merci de vous Inscrire ou de vous connectez pour voir les liens!

Pcsoft a fait un exemple avec cette dll dans la lst 98

 

Pour Zxing il te faut une procédure qui ce répète dans le temps avec ce code :

Code (Text):

PROCEDURE Scan()

MonCB est un CodeBarres
// Détection automatique de code-barres
MonCB = CBCapture(Cam)

SI PAS ErreurDétectée ET MonCB..Contenu  <> 1 ALORS
    FinAutomatismeProcédure(Scan)
    VidéoArrête(Cam, viArrêteTout)
    Ferme(F_Principale,MonCB..Contenu)
FIN
 

Ensuite 2 autres procédure son nécessaire :

Code (Text):

PROCEDURE CBCapture(ChampWebcam est un Champ, LOCAL nTypeCodeBarres est un entier = -1) : CodeBarres
sFichierTmp         est une chaîne  
pclZXINGDecoder     est un IBarcodeReader dynamique
MonCodeBarres         est un CodeBarres
MonCodeBarres..Contenu  = 1

// Génère un nom de fichier temporaire
sFichierTmp = fFichierTemp()
// Capture l'image depuis la caméra
SI VidéoCapture(ChampWebcam, sFichierTmp, viCaptureImage) ALORS
    // Charge l'image
    pclImage est une Bitmap dynamique = Bitmap.FromFile(sFichierTmp)      
   
    // Supprime le fichier temporaire
    SI PAS fSupprime(sFichierTmp) ALORS
        // Lecture de ErreurInfo pour réinitialiser ErreurDétectée
        ErreurInfo()
    FIN
   
    // Charge le décodeur
    pclZXINGDecoder = allouer un BarcodeReader()
   
    // Décode l'image
    pclRésultat est un ZXing.RESULT dynamique = pclZXINGDecoder.Decode(pclImage)
    SI pclRésultat <> Null ALORS
       
        bCodeBarresValide    est un booléen = Vrai          
        sContenu            est une chaîne = pclRésultat.Text          
       
                    // ASTUCE
                    // Pour dessiner les limites du code-barres à l'écran, dé-commentez le code ci-dessous :
       
//                    tabPoints            est un tableau de ResultPoint dynamique = pclRésultat.ResultPoints
//      
//                    // Remplacez <Champ> par le nom du champ dans lequel l'image sera affichée                      
//                    dDébutDessin(ChampWebcam, dEffacer)
//                  
//                    // 2 points
//                    si tabPoints..Occurrence = 2 ALORS
//                        dligne(tabPoints[1].X, tabPoints[1].Y, tabPoints[2].X, tabPoints[2].Y, RougeClair, 4)
//                  
//                    // 4 points
//                    sinon SI tabPoints..Occurrence = 4 _et_ (pclRésultat.BarcodeFormat dans (BarcodeFormat::EAN_13, BarcodeFormat::UPC_A)) ALORS        
//                        dLigne(tabPoints[1].X, tabPoints[1].Y, tabPoints[2].X, tabPoints[2].Y, RougeClair, 3)
//                        dLigne(tabPoints[3].X, tabPoints[3].Y, tabPoints[4].X, tabPoints[4].Y, RougeClair, 3)
//                    sinon
//                        dstylo(rougeclair, 0, 10)
//                        pour tout pclPoint de tabPoints
//                            dpoint(pclPoint.X,pclPoint.Y, rougeclair)
//                        FIN
//                    FIN
       
        // Selon le format                                  
        SELON pclRésultat.BarcodeFormat
            CAS BarcodeFormat::QR_CODE
                MonCodeBarres.TypeCodeBarres = CB_QRCODE
            CAS BarcodeFormat::CODABAR
                MonCodeBarres.TypeCodeBarres = CB_CODABAR
            CAS BarcodeFormat::CODE_39
                MonCodeBarres.TypeCodeBarres = CB_CODE39
            CAS BarcodeFormat::CODE_93
                MonCodeBarres.TypeCodeBarres = CB_CODE93
            CAS BarcodeFormat::CODE_128
                MonCodeBarres.TypeCodeBarres = CB_CODE128
            CAS BarcodeFormat::DATA_MATRIX
                MonCodeBarres.TypeCodeBarres = CB_DATAMATRIX
            CAS BarcodeFormat::EAN_8
                MonCodeBarres.TypeCodeBarres = CB_EAN8
               
                // Si le caractère de contrôle est inséré, on le supprime
                SI Taille(sContenu) > 7 ALORS sContenu = sContenu[[A 7]]
               
            CAS BarcodeFormat::EAN_13
                MonCodeBarres.TypeCodeBarres = CB_EAN13
               
                // Si le caractère de contrôle est inséré, on le supprime
                SI Taille(sContenu) > 12 ALORS sContenu = sContenu[[A 12]]
            CAS BarcodeFormat::ITF
                MonCodeBarres.TypeCodeBarres = CB_INTER2OF5
            CAS BarcodeFormat::MSI
                MonCodeBarres.TypeCodeBarres = CB_MSI
            CAS BarcodeFormat::PDF_417
                MonCodeBarres.TypeCodeBarres = CB_PDF417
            CAS BarcodeFormat::UPC_A
                MonCodeBarres.TypeCodeBarres = CB_UPCA
            CAS BarcodeFormat::UPC_E
                MonCodeBarres.TypeCodeBarres = CB_UPCE
               
                // Non supportés
                // BarcodeFormat::AZTEC, BarcodeFormat::MAXICODE, BarcodeFormat::PLESSEY, ...
            // BarcodeFormat::RSS_14, barcodeFormat::RSS_EXPANDED, BarcodeFormat::UPC_EAN_EXTENSION, BarcodeFormat::All_1D
            AUTRES CAS
                bCodeBarresValide = Faux
        FIN
       
        // Si le code barre est valide
        SI bCodeBarresValide ALORS  
           
            // Vérifie si le type de code-barres correspond à celui attendu
            SI (nTypeCodeBarres <> -1 _ET_ MonCodeBarres.TypeCodeBarres = nTypeCodeBarres) _OU_ nTypeCodeBarres = -1 ALORS
               
                // Lecture du contenu          
                MonCodeBarres.Contenu = sContenu      
               
                // Lecture de ErreurInfo pour réinitialiser ErreurDétectée
                ErreurInfo()              
                RENVOYER MonCodeBarres
            FIN
        FIN
    FIN
FIN

ErreurDéclenche(404, "Aucun code-barres n'a été détecté")
RENVOYER MonCodeBarres  
 

N'oublie pas de démarrer le scan au début :

Code (Text):

// Démarre le scan
ExécuteTraitement(COMBO_CAM, trtSélection)
 

Normalement si tu a ajouter l'assemblages .NET ZXing sa devrais fonctionner j'avais fait une application avec ce code il y a longtemps.

PS:Ceci est mon code et non celui de la LST donc ajuste le pour ton projet.